/////////////////////////////////////////////
// Explo 1 B - Short version
// Copyright (C) 2007 David Olofson
/////////////////////////////////////////////

w_format target, MONO16, 16000;
w_blank target, 16000, 0;

procedure ax(a)
{
	w_env AMPLITUDE,
			0,	a,
			.5,	a/2,
			.5,	0;
}

procedure f(tp, f0, res)
{
	w_env FREQUENCY, f0;
	w_env AMPLITUDE, res;
	w_filter target, tp;
}

// Rumble
ax .3;
w_env FREQUENCY, 130;
w_osc target, NOISE;
f LOWPASS_12, 80, 2;

// Crackle
ax .8;
w_env FREQUENCY, 350;
w_osc target, NOISE;

// Attack
ax .4;
w_env FREQUENCY, 5000;
w_osc target, NOISE;

// Mod
w_env AMPLITUDE, 1;
w_env FREQUENCY, 70;
w_env BALANCE, 1;
w_osc target, NOISE, MUL;

// Resonances
f PEAK_12, 40, 11;
f PEAK_12, 220, 8;
f PEAK_12, 900, 2;
f PEAK_12, 1100, 3;
f PEAK_12, 2700, 4;

// Treble damping
w_env FREQUENCY,
		0,	16000,
		.2,	4000,
		.8,	1000;
w_filter target, LOWPASS_6;
w_env FREQUENCY, 150;
w_env AMPLITUDE, 3;
w_env MOD1,
		0,	1,
		.2,	.4,
		.8,	0;
w_filter target, LOWPASS_12;

w_env AMPLITUDE,
		0, 	1,
		.5,	1,
		.5,	0;
w_gain target;
